zenity/configure.in

AC_PREREQ(2.53)
AC_INIT(src)
AM_CONFIG_HEADER(config.h)
AM_INIT_AUTOMAKE(zenity, 2.15.2)

GNOME_DOC_INIT

AM_MAINTAINER_MODE

IT_PROG_INTLTOOL([0.34.90])

AC_PROG_CC

GTK_REQUIRED=2.6.0

PKG_CHECK_MODULES(ZENITY, gtk+-2.0 >= $GTK_REQUIRED libglade-2.0 libgnomecanvas-2.0 glib-2.0 >= 2.7.3)
AC_SUBST(ZENITY_CFLAGS)
AC_SUBST(ZENITY_LIBS)

dnl ***********************************************
dnl scrollkeeper checks
dnl ***********************************************

AC_PATH_PROG(SCROLLKEEPER_CONFIG, scrollkeeper-config,no)
if test x$SCROLLKEEPER_CONFIG = xno; then
	AC_MSG_ERROR(Couldn't find scrollkeeper-config. Please install the scrollkeeper package)
fi

dnl *******************************
dnl perl check
dnl *******************************

AC_PATH_PROG(PERL,perl,)

dnl *******************************
dnl libnotify check
dnl *******************************
PKG_CHECK_MODULES(LIBNOTIFY, libnotify >= 0.3.2,
                  HAVE_LIBNOTIFY="yes", HAVE_LIBNOTIFY="no")
if test "x$HAVE_LIBNOTIFY" = "xyes"; then
	ZENITY_CFLAGS="$ZENITY_CFLAGS $LIBNOTIFY_CFLAGS"
	ZENITY_LIBS="$ZENITY_LIBS $LIBNOTIFY_LIBS"

	AC_SUBST(ZENITY_CFLAGS)
	AC_SUBST(ZENITY_LIBS)
	AC_DEFINE(HAVE_LIBNOTIFY, 1, [libnotify is available on this machine])
fi

dnl *******************************
dnl Internationalization
dnl ******************************* 

GETTEXT_PACKAGE=zenity
AC_SUBST(GETTEXT_PACKAGE)
AM_GLIB_GNU_GETTEXT

dnl **************************************************************
dnl AM_GLIB_GNU_GETTEXT above substs $DATADIRNAME
dnl this is the directory where the *.{mo,gmo} files are installed
dnl **************************************************************

zenitylocaledir='${prefix}/${DATADIRNAME}/locale'
AC_SUBST(zenitylocaledir)

AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE", [Finding gettext package])

AC_DEFINE_UNQUOTED(GNOME_ICONDIR, "${prefix}/share/pixmaps", [Determining icon location])

AC_OUTPUT([
Makefile 
zenity.spec
po/Makefile.in
src/Makefile
src/gdialog
data/Makefile
help/Makefile
])