AC_INIT([Zenity],[2.20.1],[http://bugzilla.gnome.org/enter_bug.cgi?product=zenity],[zenity])

AC_PREREQ([2.59])

AC_CONFIG_HEADERS([config.h])
AC_CONFIG_SRCDIR([src])

AM_INIT_AUTOMAKE([1.9 foreign dist-bzip2 no-dist-gzip])

GNOME_COMMON_INIT
GNOME_DOC_INIT

AM_MAINTAINER_MODE

IT_PROG_INTLTOOL([0.35.0])

AC_PROG_CC

GTK_REQUIRED=2.9.2

PKG_CHECK_MODULES([ZENITY],[gtk+-2.0 >= $GTK_REQUIRED libglade-2.0 libgnomecanvas-2.0 glib-2.0])
AC_SUBST([ZENITY_CFLAGS])
AC_SUBST([ZENITY_LIBS])

# *******************************
# perl check
# *******************************

AC_PATH_PROG([PERL],[perl],)

# *******************************
# libnotify check
# *******************************

LIBNOTIFY_REQUIRED=0.4.1

AC_ARG_ENABLE([libnotify],
              AC_HELP_STRING([--enable-libnotify],[enable libnotify support]),,
              [enable_libnotify=yes])

if test x$enable_libnotify = xyes ; then
   PKG_CHECK_MODULES([LIBNOTIFY],[libnotify >= $LIBNOTIFY_REQUIRED],
                     [HAVE_LIBNOTIFY="yes"],[HAVE_LIBNOTIFY="no"])

   AC_SUBST([LIBNOTIFY_CFLAGS])
   AC_SUBST([LIBNOTIFY_LIBS])

   if test "x$HAVE_LIBNOTIFY" = "xyes"; then
      AC_DEFINE([HAVE_LIBNOTIFY],[1],[libnotify is available on this machine])
   fi
fi

# *******************************
# Debug
# ******************************* 

GNOME_DEBUG_CHECK
GNOME_COMPILE_WARNINGS([maximum])

# *******************************
# Internationalization
# ******************************* 

GETTEXT_PACKAGE=zenity
AC_SUBST([GETTEXT_PACKAGE])
AC_DEFINE_UNQUOTED([GETTEXT_PACKAGE],["$GETTEXT_PACKAGE"],[Gettext domain])

AM_GLIB_GNU_GETTEXT

# *******************************

AC_SUBST([AM_CPPFLAGS])
AC_SUBST([AM_CFLAGS])
AC_SUBST([AM_LDFLAGS])

# *******************************

AC_CONFIG_FILES([
Makefile 
zenity.spec
po/Makefile.in
src/Makefile
src/gdialog
data/Makefile
help/Makefile
])

AC_OUTPUT
