plugins {
	id 'fabric-loom' version '0.2.7-SNAPSHOT'
	id 'com.matthewprenger.cursegradle' version '1.4.0'
}

compileJava {
	sourceCompatibility = JavaVersion.VERSION_1_8
	targetCompatibility = JavaVersion.VERSION_1_8
}

archivesBaseName = project.archives_base_name
def mod_version = project.mod_version as Object
version = "${mod_version}+${project.minecraft_version}"
group = project.maven_group as Object

minecraft {
}

repositories {
	jcenter()
	maven {
		url "https://dl.bintray.com/shedaniel/autoconfig1u/"
	}
}

dependencies {
	minecraft "com.mojang:minecraft:${project.minecraft_version}"
	mappings "net.fabricmc:yarn:${project.minecraft_version}+build.${project.yarn_build}:v2"
	modImplementation "net.fabricmc:fabric-loader:${project.fabric_loader_version}"
	modImplementation "net.fabricmc.fabric-api:fabric-api:${project.fabric_api_version}"

	modImplementation "me.shedaniel.cloth:config-2:${project.cloth_config_version}"
	include "me.shedaniel.cloth:config-2:${project.cloth_config_version}"
	modImplementation "me.sargunvohra.mcmods:autoconfig1u:${project.auto_config_version}"
	include "me.sargunvohra.mcmods:autoconfig1u:${project.auto_config_version}"
	modImplementation "io.github.prospector:modmenu:${project.mod_menu_version}"
}

processResources {
	inputs.property 'version', mod_version
	inputs.property 'name', rootProject.name

	from(sourceSets.main.resources.srcDirs) {
		include 'fabric.mod.json'
		expand 'version': mod_version, 'name': rootProject.name
	}

	from(sourceSets.main.resources.srcDirs) {
		exclude 'fabric.mod.json'
	}
}

// ensure that the encoding is set to UTF-8, no matter what the system default is
// this fixes some edge cases with special characters not displaying correctly
// see http://yodaconditions.net/blog/fix-for-java-file-encoding-problems-with-gradle.html
tasks.withType(JavaCompile) {
	options.encoding = 'UTF-8'
}

// Loom will automatically attach sourcesJar to a RemapSourcesJar task and to the "build" task
// if it is present.
// If you remove this task, sources will not be generated.
task sourcesJar(type: Jar, dependsOn: classes) {
	classifier 'sources'
	from sourceSets.main.allSource
}

task javadocJar(type: Jar, dependsOn: javadoc) {
	classifier 'javadoc'
	from javadoc.destinationDir
}

artifacts {
	archives sourcesJar
	archives javadocJar
}

jar {
	from "LICENSE"
}

if (project.hasProperty('curseforge.api_key')) {
	curseforge {
		apiKey = project.getProperty('curseforge.api_key')
		project {
			id = project.curseforge_id
			changelog = 'A changelog can be found at https://gitea.thebrokenrail.com/TheBrokenRail/SorceryCraft/src/branch/master/CHANGELOG.md'
			releaseType = 'release'
			addGameVersion project.simple_minecraft_version
			addGameVersion 'Fabric'
			mainArtifact(remapJar) {
				displayName = "SorceryCraft v${mod_version} for ${project.minecraft_version}"
			}
			afterEvaluate {
				uploadTask.dependsOn('remapJar')
			}
			relations {
				requiredDependency 'fabric-api'
			}
		}
		options {
			forgeGradleIntegration = false
		}
	}
}