ScriptCraft/build.gradle

plugins {
	id 'fabric-loom' version '0.2.7-SNAPSHOT'
	id 'com.matthewprenger.cursegradle' version '1.4.0'
}

def cDir = new File(rootProject.projectDir.absolutePath, 'src/main/c')

class JNIPlatform {
	String name
	String[] cmakeArgs
	String libExtension

	JNIPlatform(String name, String libExtension, File rootDir) {
		this.name = name
		this.cmakeArgs = ["-DCMAKE_TOOLCHAIN_FILE=${rootDir.absolutePath}/cmake/${name}-toolchain.cmake"] as String[]
		this.libExtension = libExtension
	}
}

JNIPlatform[] jniPlatforms = [
		new JNIPlatform("linux-x86_64", ".so", rootDir),
		new JNIPlatform("linux-x86", ".so", rootDir),
		new JNIPlatform("linux-armhf", ".so", rootDir),
		new JNIPlatform("linux-arm64", ".so", rootDir),
		new JNIPlatform("windows-x86_64", ".dll", rootDir),
		new JNIPlatform("windows-x86", ".dll", rootDir)
]

task cleanJNI {}
task compileJNI {}

for (JNIPlatform platform : jniPlatforms) {
	def buildDir = new File(cDir, "build-${platform.name}")
	if (!buildDir.exists()) {
		buildDir.mkdir()
	}

	tasks.create(name: "cmake-${platform.name}", group: 'jni', type: Exec) {
		workingDir buildDir

		executable 'cmake'
		args platform.cmakeArgs + ['..']
	}

	tasks.create(name: "compileJNI-${platform.name}", group: 'jni', type: Exec) {
		workingDir buildDir

		executable 'make'

		dependsOn tasks.getByName("cmake-${platform.name}")
	}

	compileJNI.dependsOn tasks.getByName("compileJNI-${platform.name}")

	tasks.create(name: "cleanJNI-${platform.name}", group: 'jni', type: Delete) {
		delete buildDir.absolutePath
	}

	cleanJNI.dependsOn tasks.getByName("cleanJNI-${platform.name}")
}

clean.dependsOn cleanJNI
processResources.dependsOn compileJNI

compileJava {
	sourceCompatibility = JavaVersion.VERSION_1_8
	targetCompatibility = JavaVersion.VERSION_1_8
}

archivesBaseName = project.archives_base_name
def mod_version = project.mod_version as Object
version = "${mod_version}+${project.minecraft_version}"
group = project.maven_group as Object

minecraft {
}

dependencies {
	minecraft "com.mojang:minecraft:${project.minecraft_version}"
	mappings "net.fabricmc:yarn:${project.minecraft_version}+build.${project.yarn_build}:v2"
	modImplementation "net.fabricmc:fabric-loader:${project.fabric_loader_version}"
	modImplementation "net.fabricmc.fabric-api:fabric-api:${project.fabric_api_version}"
}

def typescriptOut = new File(buildDir, 'generated/typescript')

sourceSets {
	main {
		resources {
			srcDir typescriptOut
		}
	}
}

def typescriptRoot = rootProject.typescript_root as String
def resources = new File(rootProject.rootDir, 'src/main/resources')
def typescriptRootFile = new File(resources, typescriptRoot)

task typescript(group: 'build') {
	inputs.dir typescriptRootFile
	outputs.dir typescriptOut

	doFirst {
		project.delete {
			delete typescriptOut
		}
		typescriptOut.mkdirs()

		project.exec {
			executable 'tsc'

			args '--outDir', new File(typescriptOut, typescriptRoot).absolutePath
			args '--project', typescriptRootFile.absolutePath
		}
	}
}

processResources.dependsOn typescript

def typedocOut = new File(buildDir, 'typedoc')

task typedoc(group: 'documentation') {
	inputs.dir typescriptRootFile
	outputs.dir typedocOut

	doFirst {
		project.delete {
			delete typedocOut
		}
		typedocOut.mkdirs()

		project.exec {
			workingDir typescriptRootFile
			executable 'typedoc'

			args '--out', typedocOut.absolutePath
		}
	}
}

processResources {
	inputs.property 'version', mod_version
	inputs.property 'name', rootProject.name

	from(sourceSets.main.resources.srcDirs) {
		include 'fabric.mod.json'
		expand 'version': mod_version, 'name': rootProject.name
	}

	from(sourceSets.main.resources.srcDirs) {
		exclude 'fabric.mod.json'
	}

	exclude typescriptRoot + '/**/*.ts'
	exclude typescriptRoot + '/types'

	for (JNIPlatform platform : jniPlatforms) {
		def buildDir = new File(cDir, "build-${platform.name}")
		if (!buildDir.exists()) {
			buildDir.mkdir()
		}

		def file = new File(buildDir, 'libscriptcraft' + platform.libExtension)
		inputs.files file

		from(file.absolutePath) {
			into new File('natives', platform.name).path
		}
	}
}

// ensure that the encoding is set to UTF-8, no matter what the system default is
// this fixes some edge cases with special characters not displaying correctly
// see http://yodaconditions.net/blog/fix-for-java-file-encoding-problems-with-gradle.html
tasks.withType(JavaCompile) {
	options.encoding = 'UTF-8'
}

// Loom will automatically attach sourcesJar to a RemapSourcesJar task and to the "build" task
// if it is present.
// If you remove this task, sources will not be generated.
task sourcesJar(type: Jar, dependsOn: classes) {
	classifier 'sources'
	from sourceSets.main.allSource
}

task typedocJar(type: Jar) {
	classifier 'typedoc'
	from typedocOut
}

typedocJar.dependsOn typedoc

artifacts {
	archives sourcesJar
	archives typedocJar
}

jar {
	from 'LICENSE'
}

if (project.hasProperty('curseforge.api_key')) {
	curseforge {
		apiKey = project.getProperty('curseforge.api_key')
		project {
			id = project.curseforge_id
			changelog = 'A changelog can be found at https://gitea.thebrokenrail.com/TheBrokenRail/ScriptCraft/src/branch/master/CHANGELOG.md'
			releaseType = 'release'
			addGameVersion project.simple_minecraft_version
			addGameVersion 'Fabric'
			mainArtifact(remapJar) {
				displayName = "ScriptCraft v${mod_version} for ${project.minecraft_version}"
			}
			afterEvaluate {
				uploadTask.dependsOn('remapJar')
			}
			relations {
				requiredDependency 'fabric-api'
			}
		}
		options {
			forgeGradleIntegration = false
		}
	}
}