MTU-Dining/app/build.gradle.kts

plugins {
    id("com.android.application")
}

android {
    namespace = "com.thebrokenrail.mtudining"
    compileSdk = 34

    defaultConfig {
        applicationId = "com.thebrokenrail.mtudining"
        minSdk = 21
        targetSdk = 34
        versionCode = 1
        versionName = "1.0"

        testInstrumentationRunner = "androidx.test.runner.AndroidJUnitRunner"
    }

    buildTypes {
        release {
            isMinifyEnabled = true
            isShrinkResources = true
            proguardFiles(getDefaultProguardFile("proguard-android-optimize.txt"), "proguard-rules.pro")
        }
    }
    compileOptions {
        sourceCompatibility = JavaVersion.VERSION_1_8
        targetCompatibility = JavaVersion.VERSION_1_8
        // Desugaring (Java 8+ APIs)
        isCoreLibraryDesugaringEnabled = true
    }

    // Release Builds
    val keystoreFile = File(rootDir, "keystore.jks")
    if (keystoreFile.exists()) {
        signingConfigs {
            create("release") {
                keyAlias = "key0"
                keyPassword = "password"
                storeFile = keystoreFile
                storePassword = "password"
            }
        }
        buildTypes {
            release {
                signingConfig = signingConfigs["release"]
            }
        }
    }
}

dependencies {
    implementation("androidx.appcompat:appcompat:1.6.1")
    implementation("com.google.android.material:material:1.11.0")
    // OkHttp (For HTTP)
    implementation("com.squareup.okhttp3:okhttp:4.12.0")
    // Moshi (For JSON)
    implementation("com.squareup.moshi:moshi:1.15.0")
    // Desugaring
    coreLibraryDesugaring("com.android.tools:desugar_jdk_libs:2.0.4")
}