plugins {
    id "fabric-loom" version "0.5-SNAPSHOT"
    id "com.matthewprenger.cursegradle" version "1.4.0"
    id "maven-publish"
}

compileJava {
    sourceCompatibility = JavaVersion.VERSION_1_8
    targetCompatibility = JavaVersion.VERSION_1_8
}

version = "${project.mod_version}+${project.minecraft_version}"
group = project.maven_group as Object

loom {
    accessWidener "src/main/resources/energonrelics.accesswidener"
}

repositories {
    maven {
        name = "Earthcomputer Mods"
        url = "https://dl.bintray.com/earthcomputer/mods"
    }
}

dependencies {
    minecraft "com.mojang:minecraft:${project.minecraft_version}"
    mappings "net.fabricmc:yarn:${project.minecraft_version}+build.${project.yarn_build}:v2"
    modImplementation "net.fabricmc:fabric-loader:${project.fabric_loader_version}"

    modImplementation "net.fabricmc.fabric-api:fabric-api:${project.fabric_api_version}"

    modImplementation("io.github.prospector:modmenu:${project.modmenu_version}") {
        exclude group: "net.fabricmc.fabric-api"
    }

    modCompileOnly "me.shedaniel:RoughlyEnoughItems-api:${project.roughlyenoughitems_version}"
    modRuntime("me.shedaniel:RoughlyEnoughItems:${project.roughlyenoughitems_version}") {
        exclude group: "net.fabricmc.fabric-api"
    }

    modImplementation "me.shedaniel.cloth:config-2:${project.cloth_config_version}"
    include "me.shedaniel.cloth:config-2:${project.cloth_config_version}"

    modImplementation "me.sargunvohra.mcmods:autoconfig1u:${project.autoconfig_version}"
    include "me.sargunvohra.mcmods:autoconfig1u:${project.autoconfig_version}"

    compileOnly "org.jetbrains:annotations:${project.jetbrains_annotations_version}"
}

publishing {
    publications {
        //noinspection GroovyAssignabilityCheck
        mavenJava(MavenPublication) {
            //noinspection GroovyAssignabilityCheck
            artifact(remapJar) {
                //noinspection GroovyAssignabilityCheck
                builtBy remapJar
            }
        }
    }
    repositories {
        maven {
            url "/data/maven"
        }
    }
}

processResources {
    inputs.property "version", project.version

    from(sourceSets.main.resources.srcDirs) {
        include "fabric.mod.json"
        expand "version": project.version
    }

    from(sourceSets.main.resources.srcDirs) {
        exclude "fabric.mod.json"
    }
}

// ensure that the encoding is set to UTF-8, no matter what the system default is
// this fixes some edge cases with special characters not displaying correctly
// see http://yodaconditions.net/blog/fix-for-java-file-encoding-problems-with-gradle.html
tasks.withType(JavaCompile) {
    options.encoding = "UTF-8"
}

// Loom will automatically attach sourcesJar to a RemapSourcesJar task and to the "build" task
// if it is present.
// If you remove this task, sources will not be generated.
task sourcesJar(type: Jar, dependsOn: classes) {
    classifier "sources"
    from sourceSets.main.allSource
}

jar {
    from "LICENSE"
}

javadoc {
    title "EnergonRelics v${version}"
}

if (project.hasProperty("curseforge.api_key")) {
    curseforge {
        apiKey = project.getProperty("curseforge.api_key")
        //noinspection GroovyAssignabilityCheck
        project {
            id = project.curseforge_id
            changelog = "A changelog can be found at https://gitea.thebrokenrail.com/TheBrokenRail/EnergonRelics/src/branch/master/CHANGELOG.md"
            releaseType = mod_version.startsWith("0") || mod_version.endsWith("-unstable") ? "beta" : "release"
            addGameVersion project.simple_minecraft_version
            addGameVersion "Fabric"
            mainArtifact(remapJar) {
                displayName = "EnergonRelics v${mod_version} for ${project.minecraft_version}"
            }
            afterEvaluate {
                uploadTask.dependsOn("remapJar")
            }
            relations {
                requiredDependency "fabric-api"
            }
        }
        options {
            forgeGradleIntegration = false
        }
    }
}